7
/*  $Id: theme_mngr.menu,v 1.1 1995/04/06 00:43:03 markz released $
/*--------------------------------------------------------------------------
/*            Environmental Systems Research Institute
/*--------------------------------------------------------------------------
/*    Menu: THEME_MNGR.MENU 
/* Purpose: Display list of current themes in a view
/*-------------------------------------------------------------------------- 
/* Globals: 
/*-------------------------------------------------------------------------- 
/*   Calls: theme_mngr.aml 
/*-------------------------------------------------------------------------- 
/*   Notes: 
/*-------------------------------------------------------------------------- 
/* History: Matt McGrath - 10/29/92 - Original coding 
/*          Matt McGrath - 07/14/93 - Use -PAIRS option for input fields
/*          Clayton Crawford - 12/15/93 - add mapscale specification
/*==========================================================================
 >> %view                   
                          %2d
 %ic
     ^Themes              ^Draw list
 %themes                  %dlist



                      %rt


                      %lt


                               %up  %dn

 %new    %edit             %draw  %clear
 %copy   %delete           %drawselected
 %creat            

 %quit  %help           Scale  1:%mapscale
%view DISPLAY .view$identifier 20
%2d CHOICE .view$class HELP 'Specify planimetric or surface view' ~
    RETURN '&run theme_mngr 2d_3d_choice' ~
    PAIRS 2-D 2D 3-D 3D
%ic DISPLAY .theme_mngr$icon 2 ICON 
%themes INPUT .theme_mngr$cur_theme 21 SCROLL YES TYPEIN NO ROWS 10 ~
   RETURN '&run theme_mngr active_theme' ~
   CHOICE -PAIRS %.theme_mngr$themelist% -VAR .theme_mngr$cur_theme_val
%dlist INPUT .theme_mngr$cur_drawtheme 21 SCROLL YES TYPEIN NO ROWS 10 ~
   CHOICE -PAIRS %.theme_mngr$drawlist% -VAR .theme_mngr$cur_drawtheme_val
%rt BUTTON HELP 'Add theme to draw list' ~
    ICON right16.icon '-->' ~
    &run theme_mngr add_to_drawlist
%lt BUTTON HELP 'Remove theme from draw list' ~
    ICON left16.icon '<--' ~
    &run theme_mngr remove_from_drawlist
%up BUTTON HELP 'Move theme up one in the draw list' ~
    ICON up16.icon 'Up' ~
    &run theme_mngr move_up
%dn BUTTON HELP 'Move theme down one in the draw list' ~
    ICON down16.icon 'Down' ~
    &run theme_mngr move_down
%draw BUTTON HELP 'Draw themes in draw list' ~
    Draw &run theme_mngr draw
%drawselected BUTTON HELP 'Draw currently selected theme in draw list' ~
    'Draw choice' &run theme_mngr drawselected
%clear BUTTON HELP 'Clear screen' ~
    Clear &run theme_mngr clear 
/*&run theme_mngr clear
%new BUTTON RETURN KEEP HELP 'Add a new theme' ~
    New... &run theme_mngr new_theme
%delete BUTTON HELP 'Delete the currently active theme' ~
    Delete &run theme_mngr delete_theme
/*%table BUTTON HELP 'Specify query items for currently active theme' ~
/*    Table... &run theme_mngr table
%edit BUTTON HELP 'Modify the currently active theme' ~
    Edit.. &run theme_mngr edit_theme
%copy BUTTON HELP 'Make a copy of the currently active theme' ~
     'Copy  ' &run theme_mngr duplicate_theme
%creat BUTTON HELP 'Create a coverage from currently active theme' ~
     'Create cover...' &run theme_mngr create_coverage
%quit BUTTON CANCEL HELP 'Quit from this application' ~
    'Quit' &run theme_mngr cancel
%help BUTTON RETURN KEEP ~
    HELP 'Display help for this menu' ~
    'Help' &run theme_mngr help
%mapscale INPUT .view$mapscale 10 ~
  HELP 'Scale used for displaying view' ~
  RETURN '&run theme_mngr set_mapscale' ~
  RANGE 0.001 999999999 ~
  REQUIRED REAL
/*%tools BUTTON HELP 'Display theme tool pallette' ~
/*    'Tools...' &run theme_mngr tools
%formopt SETVARIABLES IMMEDIATE MESSAGEVARIABLE .theme_mngr$msg